Hallo Leute,
heute Nachmittag habe ich nun Zeit gehabt und ein VBScript-Tool erstellt, mit dem man jetzt einen Jahresvorlauf in Monate o. Quartale aufteilen kann. Sollten bei der Aufteilung in einem Vorlauf keine Buchungssätze vorhanden sein, weil in diesem Zeitraum keine Buchungen erfolgten, wird der Vorlauf automatisch gelöscht.
Vorgehensweise:
- Mandantendaten
Die von dem Mandanten erhaltenen Daten bzw. den DATEV-Vorlauf auf ein Laufwerk kopieren bzw. exportieren. Hier empfiehlt sich das Zentrale Exportverzeichnis von DATEV zu nutzen (L:\DATEV\...). - Dateiauswahl
Hierzu könnt Ihr per Drag & Drop den zu konvertierenden Vorlauf auf das VBSript-Tool fallen lassen und starten oder Ihr wählt die Datei einfach per Doppelklick. Es wird dann eine Dateiauswahl gestartet.
- Start der Konvertierung
Nach der Dateiauswahl wird die Konvertierungsart gewählt. Es handelt sich um eine schlichte Inputbox.
Zur Auswahl stehen m = je Monat oder q = je Quartal.
Die Exportdateien erhalten den Dateinamen mit dem Zusatz "*_MM" für Monat bzw. "*_QQ" für Quartal. Die Originaldatei wird nicht verändert oder gelöscht.
Bei Abbruch oder Falscheingabe wird der Vorgang komplett abgebrochen. - DATEV-Import
Jetzt einfach im Anschluss die konvertierten Dateien wie gewohnt über die Stapelverarbeitung importieren. Es sind keine Änderungen an den Stapelvorlaufdaten notwendig. Sämtliche Zeitraumsangaben wurden entsprechend der getroffenen Auswahl angepasst.
Am Ende der Konvertierung wird folgende Meldungen ausgeworfen.oder
Das Endergebnis sieht wie folgt aus.
Für Monat:
Für Quartal:
Ich habe den Export mit ca. 1000 Buchungssätzen auf einer WTS-Station getestet. Es hat insgesamt nur wenige Sekunden gedauert. Die Daten konnten von mir einwandfrei eingelesen werden und ich habe keine Fehlermeldungen erhalten. Auch die Belegverknüpfungen sollten einwandfrei funktionieren, da diese als GUID-Wert ja vorliegen.
So damit sollte das Thema wohl endlich endgültig der Vergangenheit angehören. Auch für zukünftige Versionen sollte alles funktionieren, da ich immer die gesamten Zeilen auslese, ohne diese zu verändern.
Und hier der Quellcode:
Const ForReading = 1
Const ForWriting = 2
Const ForAppending = 8
Const DATEVBelegdatum = 9
Const DATEVFibuVon = 14
Const DATEVFibuBis = 15
Dim fs
Dim sFileIn, f
Dim sPathOutput
Dim i, z, q
Dim sFileOut
Dim sLine
Dim sTemp, tArray
Dim sYear, iMonth
Dim sOutputFile
Dim ReadFibu
set fs = createobject("Scripting.FileSystemObject")
If WScript.Arguments.length> 0 Then
sFileIn = WScript.Arguments(0)
Else
If sFileIn="" Then sFileIn=ChooseFile()
If sFileIn="" Then WScript.Quit
End If
sPathOutput=GetPathName(sFileIn)
sFileOut = GetFileNameWithOutExtension(sFileIn)
Dim sChooseExport: sChooseExport=InputBox("Bitte wählen Sie die Exportart aus." & vbNewLine & vbNewLine & " => m = Monat" & vbNewLine & " => q = Quartal","Vorlauf trennen","m")
If sChooseExport="" Then WScript.Quit
If sChooseExport="q" Then
ReDim sOutputFile(3)
Else
ReDim sOutputFile(11)
End If
i=0
Set f = fs.OpenTextFile(sFileIn,ForReading)
Select Case LCase(sChooseExport)
Case "m" 'je Monat
For i = 0 To 11
Set sOutputFile(i)=fs.OpenTextFile(fs.BuildPath(sPathOutput, sFileOut &"_" & FormatExt((i+1),2) & ".csv") ,ForWriting,True,0)
Next
'First Step
'Write Header, erste Zeile Umwandlung Vorlaufdatum
For z = 1 To 2
sLine=f.Readline
If z = 1 Then 'Fibu-Vorlaufdatum
tArray = Split(sLine,";")
sYear = Left(tArray(DATEVFibuVon),4)
For i = 0 To 11
tArray(DATEVFibuVon)=sYear & FormatExt((i+1),2) & "01" 'Monatsanfang
If i=11 Then
tArray(DATEVFibuBis)=sYear & "1231" 'Dezember
Else
tArray(DATEVFibuBis)=sYear & FormatExt((i+1),2) & Day(DateSerial(sYear,(i+2),0)) 'Monats => 0.03.2020 => 29.02.2020
End If
For q=LBound(tArray) To UBound(tArray)
sTemp = sTemp & tArray(q) & ";"
Next
sTemp = Left(sTemp,Len(sTemp)-1)
sOutputFile(i).writeline sTemp
sTemp=""
Next
Else
For i = 0 To 11
sOutputFile(i).writeline sLine
Next
End If
Next
'End First Step
'Second Step
'Lese Fibu-Daten und verteile auf Einzevorläufe
Do Until f.AtEndOfStream
sLine = f.ReadLine
tArray=Split(sLine,";")
iMonth=Right(tArray(DATEVBelegdatum),2)
sOutputFile(CInt(iMonth)-1).writeline sLine
Loop
'End Second Step
'Last Step
'Schließe alle offenen Dateien
For i = 0 To 11
sOutputFile(i).close
If GetNumberOfLines(fs.BuildPath(sPathOutput, sFileOut &"_" & FormatExt((i+1),2) & ".csv")) <= 3 Then fs.DeleteFile(fs.BuildPath(sPathOutput, sFileOut &"_" & FormatExt((i+1),2) & ".csv"))
Next
MsgBox "Alle Buchungssätze wurden monatsweise in einzelne Vorläufe verteilt. Die alle Dateien haben den Zusatz *_MM erhalten und können jetzt importiert werden.",48,"Konvert DATEV-Fibu"
Case "q" 'je Quartal
For i = 0 To 3
Set sOutputFile(i)=fs.OpenTextFile(fs.BuildPath(sPathOutput, sFileOut &"_" & RomanNumber((i+1)) & ".csv") ,ForWriting,True,0)
Next
'First Step
'Write Header, erste Zeile Umwandlung Vorlaufdatum
For z = 1 To 2
sLine=f.Readline
If z = 1 Then 'Fibu-Vorlaufdatum
tArray = Split(sLine,";")
sYear = Left(tArray(DATEVFibuVon),4)
For i = 0 To 3
tArray(DATEVFibuVon)=sYear & FormatExt(((i+1)*3)-2,2) & "01" 'Anfang Quartal
If i=3 Then
tArray(DATEVFibuBis)=sYear & "1231" 'Dezember
Else
tArray(DATEVFibuBis)=sYear & FormatExt(((i+1)*3),2) & Day(DateSerial(sYear,((i+1)*3)+1,0)) 'Ende Quartal => 0.03.2020 => 28.02.2020
End If
For q=LBound(tArray) To UBound(tArray)
sTemp = sTemp & tArray(q) & ";"
Next
sTemp = Left(sTemp,Len(sTemp)-1)
sOutputFile(i).writeline sTemp
sTemp=""
Next
Else
For i = 0 To 3
sOutputFile(i).writeline sLine
Next
End If
Next
'End First Step
'Second Step
'Lese Fibu-Daten und verteile auf Einzevorläufe
Do Until f.AtEndOfStream
sLine = f.ReadLine
tArray=Split(sLine,";")
iMonth=Right(tArray(DATEVBelegdatum),2)
Select Case True
Case iMonth >= 1 And iMonth <= 3
sOutputFile(0).writeline sLine
Case iMonth >= 4 And iMonth <= 6
sOutputFile(1).writeline sLine
Case iMonth >= 7 And iMonth <= 9
sOutputFile(2).writeline sLine
Case iMonth >= 10 And iMonth <= 12
sOutputFile(3).writeline sLine
End Select
Loop
'End Second Step
'Last Step
'Schließe alle offenen Dateien
For i = 0 To 3
sOutputFile(i).close
If GetNumberOfLines(fs.BuildPath(sPathOutput, sFileOut &"_" & RomanNumber((i+1)) & ".csv")) <= 3 Then fs.DeleteFile(fs.BuildPath(sPathOutput, sFileOut &"_" & RomanNumber((i+1)) & ".csv"))
Next
MsgBox "Alle Buchungssätze wurden monatsweise in einzelne Vorläufe verteilt. Die alle Dateien haben den Zusatz *_QQ erhalten und können jetzt importiert werden.",48,"Konvert DATEV-Fibu"
Case Else
MsgBox "Sie haben eine falsche Auswahl getroffen. Erlaubt ist nur je Monat (m) oder je Quartal (q)." & vbNewLine & vbNewLine & "Bitte wiederholen Sie den Vorgang.",48,"Falsche Auswahl Exportart"
WScript.Quit
End Select
'Hilfsfunktionen
'---------------
Function GetPathName(sFilePath)
sFilePath = Replace(sFilePath, "/" , "\")
GetPathName = Left(sFilePath, InStrRev(sFilePath, "\"))
End Function
Function GetFileName(sFilePath)
GetFileName = fs.GetFileName(sFilePath)
End Function
Function GetFileNameWithOutExtension(sFilePath)
GetFileNameWithOutExtension = fs.GetBaseName(sFilePath)
End Function
Function FormatExt(Zahl,Anzahl)
FormatExt= Right(String(Anzahl, "0") & zahl,Anzahl)
End Function
Function GetNumberOfLines(strFile)
Dim ts
Set ts = fs.OpenTextFile(strFile)
ts.ReadAll
GetNumberOfLines = ts.Line
End Function
Function FormatExt(Zahl,Anzahl)
FormatExt= Right(String(Anzahl, "0") & zahl,Anzahl)
End Function
Function RomanNumber(Number)
Dim Result
Select Case Number
Case 1 : Result="I"
Case 2 : Result="II"
Case 3 : Result="III"
Case 4 : Result="IV"
End Select
RomanNumber=Result
End Function
Function ChooseFile()
Set oExec=CreateObject("WScript.Shell").Exec( "mshta.exe ""about:" & "<" & "input type=file id=FILE>" & "<" & "script>FILE.click();new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1).WriteLine(FILE.value);close();resizeTo(0,0);" & "<" & "/script>""" )
Tst = oExec.StdOut.ReadAll
Tst = Replace( Tst, vbCRLF, "" )
ChooseFile= Tst
End Function
Den Code einfach kopieren und in eine Textdatei einfügen. Anschließend die Datei umbenennen in z. B. SeparateDATEFibu.vbs, wichtig ist die Extension "VBS".
Ich übernehme keine Verantwortung für Schäden am Datenbestand oder System. Es werden von mir keine Änderungen am System vorgenommen. Anspruch auf Support besteht nicht, stehe aber gerne für Probleme und Fragen hier im Forum zur Verfügung.
Gruß Achilleus
Hallo @Gelöschter Nutzer ,
habe mal 12 laaange Monats-Stapel zu einem noch lääängeren Jahres-Stapel zusammengefasst (gesamt: 155.667 Zeilen) und anschließend mit Ihrem Script beim ersten Test in 12 Monats-Stapel und beim zweiten Test in 4 Quartals-Stapel aufteilen lassen.
... Die Aufteilung war jeweils eine Sache von nur wenigen Sekunden 😊
An der Formulierung könnte man vielleicht noch etwas feilen, aber die eigentliche Arbeit ist sehr, sehr schnell erledigt.
Da kann man sich viel früher dem Vergnügen widmen 😄
... verprobt habe ich noch nicht, werde ich aber bei Gelegenheit noch tun
Bravo, @Gelöschter Nutzer !
Danke !
Hallo Achilleus,
was mache ich falsch? Bei mir kommt bei Anwendung des Tools folgende Meldung:
Gruß Niels Ommen
Könnten Sie mir noch ein paar mehr Infos geben?
Haben Sie denn auch einen DATEV-Vorlauf genommen?
Vielleicht stellen Sie einmal ein Screenshot mit den Headerzeilen ein.
So kann ich wenig dazu sagen. 😏
Gruß Achilleus